*** Elimination theory ***
----------------------------------------------
-- 
----------------------------------------------
-- Elimination theory addresses the general ideas 
-- of elimination of variables (from the algebraic point of view)
-- and dimension reduction (from the geometric point of view)
-- in systems of polynomial equations and varieties they define, respectively. 
--
-- * Eliminating monomial orders
--
-- * Solving systems of equations
--
-- * Projection of varieties


----------------------------------------------
-- Eliminating monomial orders
----------------------------------------------
-- The lexicographic order 

Rlex = QQ[x,y,z,MonomialOrder=>Lex]   

-- can be considered as an order eliminating {x} and {x,y}.
-- Let us ``eliminate'' variables from the system of polynomials

F = {x^2+y^2+z^2-4, x^2+2*y^2-5, x*y*z-y}

-- by computing a Gröbner basis:

getGB = flatten@@entries@@gens@@gb@@ideal
G = getGB F

-- Notice that 
take(G,1)
-- generates the ideal $I {\cap} \QQ[z]$, where $I=<F>$, and
take(G,3)
-- are generators of $I {\cap} \QQ[y,z]$.
--
-- There are other ways to define elimination orders: for example, one may specify the number of variables to eliminate

Re1 = QQ[x,y,z,MonomialOrder=>Eliminate 1] 
getGB sub(matrix{F},Re1)

-- or give positive weights to the variables that ought to be eliminated and zero to the rest

R100 = QQ[x,y,z,Weights=>{1,2,0}]
getGB sub(matrix{F},R100)

-- There is also a blackbox function which eliminates specified variables and returns the generators of intersection with the subring of polynomials in the remaining variables:

use Rlex
eliminate({x},ideal F) 
eliminate({x,y},ideal F)


----------------------------------------------
-- Solving systems of equations
----------------------------------------------
-- If a system of polynomial equations 
-- has finitely many solutions (over an algebraically closed field: think $\mathbb C$)
-- then they can be found via elimination.

-- Passing form polynomials $F$ to the Gröbner basis $G$ (see the preceding part)
-- we, in particular, get a univariate polynomial in $z$ that factors (over $\QQ$).
use Rlex; print F; print G; 
factor G#0
-- It reveals in particular that there is a point in $V(F)$ with $z=1$.
-- Substituting $z=1$ in the polynomials in $G {\cap} \QQ[y,z]$ 
apply(0..2, i->sub(G#i,{z=>1}))
-- we see that the $y$-coordinate can take the values plus or minus square root of $2$, which are not in $\QQ$.
-- One way to carry on is to extend $\QQ$:
QQa = toField(QQ[a]/(a^2-2))
-- The point $(x,a,1)$ has to satisfy the following equations:
M = map(QQa[x],Rlex,{x,a,1}) -- (x,y,z) maps to (x,a,1)
equations'for'x = apply(G,g->M g)  
-- There is only one possible value for $x$, since
gcd equations'for'x
-- Conclusion: there are two points in $k^3$, $k=\QQ(\alpha^2-2)$, whose projection to the $xy$-plane is $(0,0,1)$, namely $(1,\alpha,1)$ and $(1,-\alpha,1)$.

----------------------------------------------
-- Projection
----------------------------------------------
-- Consider the problem of projecting the
-- ``twisted cubic'', a curve in ${\mathbb C}^3$ that can be defined
-- by the three $2\times 2$ minors of a
-- $2\times 3$ matrix into the plane.  

QQ[x,y,z]
I = minors(2, matrix{{1,x,y},{x,y,z}})

-- Such problems can be solved in a very 
-- simple and direct way using Gröbner bases.
-- The technique lends itself to many extensions,
-- and in its developed form can be used to find
-- the closure of the image of any map of 
-- affine varieties.  

-- Here is how the twisted cubic ``looks'' projected to the coordinate planes:
eliminate({x},I)
eliminate({y},I)
eliminate({z},I)

-- We can also project to an arbitrary plane along an arbitrary projection map by considering a linear change of variables:
eliminate(x, sub(I, {x=>x+y+z+1, y=>x+2*y+3*z+5, z=>z}))

----------------------------------------------
-- Implicitization
----------------------------------------------
-- {\em Whitney umbrella} surface $W$ is parametrized by $x = uv, y = v, z = u^2$. To find the implicit description (equations in
-- $x,y,z$) for $W$ we consider the graph $\Gamma_\phi$ of the map
-- $$\phi(u,v)=(uv,v,u^2)$$ and construct its vanishing ideal $I = {\mathbb I}(\Gamma_\phi)$,

QQ[u,v,x,y,z]; I = ideal(x - u*v, y - v, z - u^2)

-- Eliminating $u$ and $v$ we get an ideal

J = eliminate({u,v},I)

-- such that ${\mathbb V}(J) = $Zariski closure$(\phi({\mathbb C}^2))$.