*** Local rings ***
----------------------------------------------
-- 
----------------------------------------------
-- Computations in local rings can be handled via standard bases with
-- respect to local monomial orders.
--
-- * Local monomial orders and standard bases
--
-- * Bases of standard monomials and multiplicity
--
-- * Applications: Milnor number
----------------------------------------------
-- Local monomial orders
----------------------------------------------
-- For the ideal
R = QQ[x,y];
I = ideal(y^4*x+3*x^3-y^4-3*x^2, 
     x^2*y-2*x^2,
     2*y^4*x-x^3-2*y^4+x^2); 
-- we can see that ${\mathbb V}(I) = \{ (0,0), (1,2) \}$ : the radical of $I$ decomposes in 
decompose I
-- Suppose we would like to do local computations at the origin. 
-- To that define a ring 
R0 =QQ[x,y,Weights=>{-1,-1},Global=>false]
-- Note that {\tt R0} is not a local ring per se, 
-- but the specified monomial order is a refinement of the
-- weight order with negative weights and is, therefore, local.
getGB = flatten@@entries@@gens@@gb
J = sub(I,R0)
G = getGB sub(J,R0)
-- The set $G$ above is a standard basis in the local ring $R_M$ for $M=<x,y>$. 
-- Note that it can be simplified: $2x^2-x^2y = (2-y)x^2$, but $(2-y)$ is a unit in $R_M$.
-- Therefore, $\{x^2,y^4-(4/3)xy^4\}$ 
-- is a standard basis as well and, by a similar argument, 
G0 = {x^2, y^4}
-- is one as well.
----------------------------------------------
-- Bases of standard monomials and multiplicity
----------------------------------------------
-- The basis of standard monomials (do not confuse with standard
-- basis) for the quotient ring in our running example can be obtained
-- by taking a quotient with respect to ideal generated by any version of a standard basis above:
basis(R0/G) 
basis(R0/G0) 
-- The multiplicity of the origin equals the vector space dimension of
-- the quotient local ring or, in another terminology, its degree.
degree(R0/G)
-- The multiplicity of the other point in ${\mathbb V}(I)$ can be computed by shifting $(1,2)$ to the origin.
J' = sub(sub(J,{x=>x+1,y=>y+2}),R0)
getGB J'
-- From the leading monomials of the standard basis elements above, we
-- see that the other point is regular (multiplicity=1).
degree J' 
-- As we know the sum of multiplicities equals the multiplicity (vector-space dimension) of $R/I$.
degree J' + degree J == degree I
----------------------------------------------
-- Applications: Milnor number
----------------------------------------------
-- Take a polynomial function
use R0
h = poly "x5+y2+2y3+y4"
-- The partial derivatives of $h$ 
J = jacobian matrix{{h}}
-- vanish at the origin. That means that $h$ has a singularity at
-- $(0,0)$, moreover, this singularity is isolated: the localization
-- ideal generated by the derivatives is 0-dimensional.
I = ideal J
dim I
-- A singularity theory invariant, the {\em Milnor number}, is defined
-- as the multiplicity of the singular point and, therefore, can be
-- computed using standard bases technique.
degree I
-- Note that there are other singularities: $(0,-1)$ and $(0,-1/2))$. Their Milnor numbers are the same:
degree sub(I,{x=>x,y=>y-1}) 
degree sub(I,{x=>x,y=>y-1/2}) 
-- The geometric meaning of this invariant may be demonstrated by perturbing the function:
QQ[x,y,a,b]
h' = poly "x5+y2+2y3+y4+ax+by"
I = ideal {diff(x,h'),diff(y,h')}
-- We can see that there are, for example, 4 isolated regular points of $\mathbb V(I)$ close to $(0,0)$ if $a$ and $b$ are small.