Earth Geometry

We wish to draw a map of the surface of the Earth on a flat surface, and our objective is to avoid distorting distances.  

For this exercise, we will assume the Earth is a round sphere.

spherical radius (in miles)

rho=3959;

Here is a function which can be used to determine Euclidean coordinates in three dimensions for points on the Earth; it is the familiar spherical coordinates map.

coords[azimuth_,polar_]={rho Sin[azimuth] Cos[polar], rho Sin[azimuth] Sin[polar],rho Cos[azimuth]};

We take the origin to be the center of the Earth.

It is convenient to take the z-axis connecting the north and south poles (positive direction through the north pole) and the x-axis so that Greenwich, England is in the first quadrant of the x-z plane.

Then you can look up the lattitude and longitude of various locations, and calculate the Euclidean coordinates.

Atlanta: 33.8° N, 84.4° W

A=coords[(90-33.8) Pi/180,-84.4 Pi/180]

Paris: 48.9° N, 2.4° E

P=coords[(90-48.9) Pi/180,2.4 Pi/180]

Rio: 22.9° S, 43.2° W

R=coords[(90+22.9) Pi/180, -43.2 Pi/180]

Zanzibar: 6.1° S, 39.3° E

Z=coords[(90+6.1) Pi/180,39.3 Pi/180]

Earth / spherical distance

dist[pone_,ptwo_]=rho ArcCos[pone.ptwo/rho^2];

ap=dist[A,P]
ar=dist[A,R]
az=dist[A,Z]
pr=dist[P,R]
pz=dist[P,Z]
rz=dist[R,Z]

Now we begin to transfer this information into the Euclidean plane and construct our map.

We will start with Atlanta at the origin and place Rio and an inclination of 45° to the Southeast.

first=Show[ParametricPlot[t ar {Cos[-Pi/4],Sin[-Pi/4]},{t,0,1}],ParametricPlot[ap {Cos[t],Sin[t]},{t,0,2 Pi}],PlotRange->All]

Notice Paris will be on a circle of radius ap, the distance from Atlanta to Paris, centered at Atlanta (the origin).  The figure above shows Rio at the end of a segment along with the Paris (Atlanta centered) circle.  Notice that Paris is a little closer to Atlanta than Rio.

Also, Paris should like on a circle of radius pr centered at rio.

rio=ar {Cos[-Pi/4],Sin[-Pi/4]};

second=Show[first,ParametricPlot[rio+ pr {Cos[t],Sin[t]},{t,0, 2 Pi}],PlotRange->All]

parisangle=FindRoot[(rio+ pr {Cos[t],Sin[t]}).(rio+ pr {Cos[t],Sin[t]})-ap^2==0,{t,Pi/2}][[1,2]]

paris=rio+pr{Cos[parisangle],Sin[parisangle]}

third=Show[second,ParametricPlot[{t paris,(1-t) rio+t paris},{t,0,1}]]

Zanzibar should be at the intersection of two circles, one centered at Paris with radius pz and another centered at Rio with radius rz.  Here we plot these two circles.  

Notice that rz is a little less than pr.

fourth=Show[third,ParametricPlot[{rio+rz {Cos[t],Sin[t]},paris+pz {Cos[t],Sin[t]}},{t,0,2 Pi}],PlotRange->All]

The intersection of these two circles gives Zanzibar, which we find as follows:

zanzibarangle=FindRoot[(paris+pz {Cos[t],Sin[t]}-rio).(paris+pz {Cos[t],Sin[t]}-rio)-rz^2==0,{t,-Pi/6}][[1,2]]

zanzibar=paris+pz {Cos[zanzibarangle],Sin[zanzibarangle]}

Planar distance from Atlanta to Zanzibar

All the distances on our map indicated by straight lines are correct.  There are five of those distances, but we haven’t checked the distance from Atlanta to Zanzibar.  

Let us plot a circle centered at Zanzibar (on our map) with radius az, the spherical distance from Atlanta to Zanzibar.

Show[ParametricPlot[{t rio,t paris,(1-t) rio+t paris,(1-t) paris+t zanzibar,(1-t) rio+t zanzibar},{t,0,1}],ParametricPlot[zanzibar+az {Cos[t],Sin[t]},{t,0,2 Pi}],PlotRange->All]

Show[ParametricPlot[{t rio,t paris,(1-t) rio+t paris,(1-t) paris+t zanzibar,(1-t) rio+t zanzibar},{t,0,1}],ParametricPlot[zanzibar+az {Cos[t],Sin[t]},{t,5 Pi/6,7 Pi/6}],PlotRange->All]

az-Sqrt[zanzibar.zanzibar]

We can conclude a couple things from this exercise.  First, our planar map underestimated the distance from Atlanta to Zanzibar.  

Can you explain why is this the case?

Also, it is impossible to create a planar map which preserves all the spherical distances.  Gauss’ Theorema Egregium gives a far reaching refinement and generalization of this conclusion.

introductory comments for Math 4441 Differential Geometry

A reasonable goal for a first course in the differential geometry of curves and surfaces is to understand the answers to some of the following questions:

1. Is it possible to represent a portion of a spherical surface with marked locations, like cities on the surface of the Earth, with a planar map which preserves all spherical distances?

(The exercise above shows the answer is “no,” but we will give a much more sophisticated,  careful, technical, and general answer.  However, if this kind of question is not interesting to you, or if you feel like you know enough about the answer after reading the above, then this course is definitely not for you.)

2. How do you measure distances between points on a surface?

3. What does it mean for a surface to be curved?  How does one measure curvature of a surface?

That’s about it.  If you understand how to give some pretty complete answers to these three simple questions, then you’ve probably had a reasonable first course in differential geometry.

The above comment goes along with a disclaimer:  Many students are interested in a first course in differential geometry because they want to understand something like general relativity.  On the one hand, this course does not really get you there.  In some sense, it might not even get you very close.  On the other hand, the usual progression to understand the mathematics (which is also properly called differential geometry) needed to understand general relativity is something like this:

(a) differential geometry of curves and surfaces (this course is an introduction)
(b) Riemannian geometry (paradoxically a kind of restriction and generalization of the material in this course)
(c) semi-Riemannian geometry (a generalization of Riemannian geometry)

So the moral of the story is that there’s a pretty big step left between the material of this course and the mathematics of general relativity, but this course is often where people start in that direction.  

A further disclaimer:  The instructor of this particular course is not really an expert on either semi-Riemannian geometry or general relativity.  There is a totally different direction possible in differential geometry---at least he likes to think that---called submanifold geometry, and it’s much more closely related to the material of this course.  All that to say:  It might be helpful for you, as a student, to just concentrate on the simple questions above; there might be more to them than you would guess at first.

Enough disclaimers; let’s make some introductory comments on the answers.  

3. Our first notions of how a surface is curved are based on the idea of how curves are curved.  You might have covered some or most of this topic in Calculus.  But we will start with curves and give a somewhat more detailed treatment of that topic.  When we understand curves fairly well, we can do two things with that understanding:
(a) We can extend the basic approach to surfaces---understanding how to parameterize surfaces in general and manipulate the various associated derivatives, for example.
(b) We can interpret the curvature of surfaces in terms of the curvature of certain curves which happen to lie on those surfaces.  

2. It turns out there are two, seemingly quite different, ways to think about distances between points on a surface.  Roughly speaking one approach is “local” being based on a real valued function (the metric) which you integrate to compute lengths of general curves on the surface.  If you pick the correct path---and that choice can also be locally determined by a differential equation---then you can calculate distances between two points “relative to the surface” or “in the surface.”  The second approach involves minimizing lengths over paths which connect two points and leads to a metric in the sense of metric spaces.  The relations between these two different “metrics” and the global geometry of a surface can be quite interesting, though we will only cover some of the most elementary aspects.

1. Finally, Gauss’ theorem (the Theorema Egregium, or “big theorem”) puts these the two questions above together and says there is a notion of curvature, measured as a single real number at each point on the surface and defined in terms of how certain curves on the surface are curving in space, which can actually be computed in terms of the local metric---thus, one can “see” this curvature only by considering distances on the surface (so called intrinsic distances) without considering how curves are curving in space.  

As an application, if a sphere could be identified with (i.e., mapped into) a plane in such a manner that all distances were preserved, then these two surfaces (the plane and the sphere) would necessarily share the same Gauss curvature.  But the Gauss curvature of a plane is zero and the Gauss curvature of the sphere is nonzero, which implies the nonexistence of such a map in  a very strong sense.  Likewise, the fact that a planar map can be rolled up into a cylinder (which is curved in space) withouth distorting distances, implies that the two surfaces (the plane and the cylinder) both have the same Gauss curvature, namely, any  cylinder has zero Gauss curvature like the plane.

The theorem is quite subtle, and there are also verious elaborations and generalizations one can pursue.  Perhaps one of the nicest is called the Gauss-Bonnet theorem which relates the integral of the Gauss curvature over a piece of surface the integral over the boundary of a special intrasurface curvature of the boundary of that piece in a manner reminiscent of Green’s Theorem or Stokes’ Theorem from calculus.  

In any case, Gauss’ big theorem (and perhaps the Gauss-Bonnet theorem) is a reasonable goal for this course, so it is with details necessary for that theorem with which we will be primarly occupied.

Exercises

1. Draw (with some math software, like Matlab, Maple, or Mathematica) a sphere with Atlanta, Paris, Rio, and Zanzibar in their proper locations and the spherical geodesics connecting them.

2. Pick four other cities and construct a planar map as we have done and determine the error in the predicted distance between the first and fourth city.

3. Is it possible to position four such distinct cities (i.e., locations on a sphere) so that such a map gives the correct distance from the first city to the fourth?

4. What is the maximum error which this approach to map making might cause?  For example, the map we constructed above underestimated the correct distance from Atlanta to Zanzibar by about 769 miles.  

5. Is it ever the case that the distance between the first and fourth cities on such a map will be greater than the actual (spherical) distance?